Full width home advertisement

Arduino Simulation

Post Page Advertisement [Top]

ESP SeriesESP32 BasicPN532

Interfacing ESP32 dengan PN532 Modul (NFC/RFID reader)

Akses Modul PN532 dengan ESP32
Salah satu modul reader Smart Card yang support NFC adalah PN532. Modul ini memiliki beberapa opsi komunikasi untuk mengakses data hasil pembacaan kartu/tag. Opsi tersebut adalah SPI, I2C, dan HSU (High Speed UART). Pemilihan opsi ini dilakukan dengan mengatur posisi dip Switch yang ada pada modul. Untuk lebih jelas mengenai modul PN532 ini, dapat kita baca data sheet atau pun User manualnya secara langsung. 
Setelah mencoba mengakses modul ini menggunakan ESP32 dan beberapa library yang telah tersedia, hanya komunikasi SPI saja yang dapat bekerja secara stabil. Sementara mode HSU dapat berfungsi tetapi terdapat kendala sedangkan  mode I2C tidak dapat berfungsi sama sekali. Untuk lebih jelasnya berikut saya share hasil uji coba yang telah dilakukan.

1. Wiring
Ubah posisi dip Switch ke mode SPI (SW1=Off, SW2=ON). Pin yang digunakan adalah pin SPI untuk lokasi pin SPI pada ESP32 adalah SCK=D18, MISO=D19, MOSI=D23 sementara untuk pin SS dapat dihubungkan ke pin digital lainnya misal D5.
ESP32 Akses NFC Modul PN532

2. Program
Sebelumnya silahkan terlebih dahulu install library modul PN532. Library yang digunakan adalah Adafruit PN532 by Adafruit.
ESP32 Akses NFC Modul PN532
Dalam program, pastikan konfigurasi pin sudah sesuai dengan wiring diagram. selanjutnya langsung upload program ke modul ESP32.

#include <Wire.h>
#include <SPI.h>
#include <Adafruit_PN532.h>

// If using the breakout with SPI, define the pins for SPI communication.
#define PN532_SCK  (18)
#define PN532_MISO (19)
#define PN532_MOSI (23)
#define PN532_SS   (5)

Adafruit_PN532 nfc(PN532_SCK, PN532_MISO, PN532_MOSI, PN532_SS);

void setup(void) {
  #ifndef ESP8266
    while (!Serial); // for Leonardo/Micro/Zero
  #endif
  Serial.begin(115200);
  Serial.println("Hello!");

  nfc.begin();

  uint32_t versiondata = nfc.getFirmwareVersion();
  if (! versiondata) {
    Serial.print("Didn't find PN53x board");
    while (1); // halt
  }
  // Got ok data, print it out!
  Serial.print("Found chip PN5"); Serial.println((versiondata>>24) & 0xFF, HEX); 
  Serial.print("Firmware ver. "); Serial.print((versiondata>>16) & 0xFF, DEC); 
  Serial.print('.'); Serial.println((versiondata>>8) & 0xFF, DEC);
  
  // configure board to read RFID tags
  nfc.SAMConfig();
  
  Serial.println("Waiting for an ISO14443A Card ...");
}


void loop(void) {
  uint8_t success;
  uint8_t uid[] = { 0, 0, 0, 0, 0, 0, 0 };  // Buffer to store the returned UID
  uint8_t uidLength;                        // Length of the UID (4 or 7 bytes depending on ISO14443A card type)
    
  // Wait for an ISO14443A type cards (Mifare, etc.).  When one is found
  // 'uid' will be populated with the UID, and uidLength will indicate
  // if the uid is 4 bytes (Mifare Classic) or 7 bytes (Mifare Ultralight)
  success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, uid, &uidLength);
  
  if (success) {
    // Display some basic information about the card
    Serial.println("Found an ISO14443A card");
    Serial.print("  UID Length: ");Serial.print(uidLength, DEC);Serial.println(" bytes");
    Serial.print("  UID Value: ");
    nfc.PrintHex(uid, uidLength);
    Serial.println("");
    
    if (uidLength == 4)
    {
      // We probably have a Mifare Classic card ... 
      Serial.println("Seems to be a Mifare Classic card (4 byte UID)");
   
      // Now we need to try to authenticate it for read/write access
      // Try with the factory default KeyA: 0xFF 0xFF 0xFF 0xFF 0xFF 0xFF
      Serial.println("Trying to authenticate block 4 with default KEYA value");
      uint8_t keya[6] = { 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF };
   
   // Start with block 4 (the first block of sector 1) since sector 0
   // contains the manufacturer data and it's probably better just
   // to leave it alone unless you know what you're doing
      success = nfc.mifareclassic_AuthenticateBlock(uid, uidLength, 4, 0, keya);
   
      if (success)
      {
        Serial.println("Sector 1 (Blocks 4..7) has been authenticated");
        uint8_t data[16];
  
        // If you want to write something to block 4 to test with, uncomment
  // the following line and this text should be read back in a minute
        //memcpy(data, (const uint8_t[]){ 'a', 'd', 'a', 'f', 'r', 'u', 'i', 't', '.', 'c', 'o', 'm', 0, 0, 0, 0 }, sizeof data);
        // success = nfc.mifareclassic_WriteDataBlock (4, data);

        // Try to read the contents of block 4
        success = nfc.mifareclassic_ReadDataBlock(4, data);
  
        if (success)
        {
          // Data seems to have been read ... spit it out
          Serial.println("Reading Block 4:");
          nfc.PrintHexChar(data, 16);
          Serial.println("");
    
          // Wait a bit before reading the card again
          delay(1000);
        }
        else
        {
          Serial.println("Ooops ... unable to read the requested block.  Try another key?");
        }
      }
      else
      {
        Serial.println("Ooops ... authentication failed: Try another key?");
      }
    }
    
    if (uidLength == 7)
    {
      // We probably have a Mifare Ultralight card ...
      Serial.println("Seems to be a Mifare Ultralight tag (7 byte UID)");
   
      // Try to read the first general-purpose user page (#4)
      Serial.println("Reading page 4");
      uint8_t data[32];
      success = nfc.mifareultralight_ReadPage (4, data);
      if (success)
      {
        // Data seems to have been read ... spit it out
        nfc.PrintHexChar(data, 4);
        Serial.println("");
  
        // Wait a bit before reading the card again
        delay(1000);
      }
      else
      {
        Serial.println("Ooops ... unable to read the requested page!?");
      }
    }
  }
}
PN532 modul with ESP32

PN532 modul with ESP32

Tidak ada komentar:

Posting Komentar

Bottom Ad [Post Page]

| Designed by Colorlib